plugins {
	id 'com.android.application'
	id 'kotlin-android'
	id 'kotlin-kapt'
	id 'kotlin-parcelize'
}

android {
	compileSdkVersion 31
	buildToolsVersion '30.0.3'

	defaultConfig {
		applicationId 'org.koitharu.kotatsu'
		minSdkVersion 21
		targetSdkVersion 31
		versionCode 378
		versionName '2.1.2'
		generatedDensities = []
		testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"

		kapt {
			arguments {
				arg 'room.schemaLocation', "$projectDir/schemas".toString()
			}
		}
	}
	compileOptions {
		sourceCompatibility JavaVersion.VERSION_1_8
		targetCompatibility JavaVersion.VERSION_1_8
	}
	buildTypes {
		debug {
			applicationIdSuffix = '.debug'
		}
		release {
			multiDexEnabled false
			minifyEnabled true
			shrinkResources true
			proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
		}
	}
	buildFeatures {
		viewBinding true
	}
	sourceSets {
		androidTest.assets.srcDirs += files("$projectDir/schemas".toString())
	}
	lintOptions {
		disable 'MissingTranslation'
		abortOnError false
	}
	testOptions {
		unitTests.includeAndroidResources = true
		unitTests.returnDefaultValues = false
	}
}
tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
	kotlinOptions {
		jvmTarget = JavaVersion.VERSION_1_8.toString()
		freeCompilerArgs += [
				'-Xopt-in=kotlinx.coroutines.ExperimentalCoroutinesApi',
				'-Xopt-in=kotlin.contracts.ExperimentalContracts',
		]
	}
}
dependencies {
	implementation fileTree(dir: 'libs', include: ['*.jar', '*.aar'])
	implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-core:1.6.0'
	implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-android:1.6.0'

	implementation 'androidx.core:core-ktx:1.7.0'
	implementation 'androidx.activity:activity-ktx:1.4.0'
	implementation 'androidx.fragment:fragment-ktx:1.4.0'
	implementation 'androidx.lifecycle:lifecycle-runtime-ktx:2.4.0'
	implementation 'androidx.lifecycle:lifecycle-viewmodel-ktx:2.4.0'
	implementation 'androidx.lifecycle:lifecycle-livedata-ktx:2.4.0'
	implementation 'androidx.lifecycle:lifecycle-service:2.4.0'
	implementation 'androidx.lifecycle:lifecycle-process:2.4.0'
	implementation 'androidx.constraintlayout:constraintlayout:2.1.3'
	implementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
	implementation 'androidx.recyclerview:recyclerview:1.2.1'
	implementation 'androidx.viewpager2:viewpager2:1.1.0-beta01'
	implementation 'androidx.preference:preference-ktx:1.1.1'
	implementation 'androidx.work:work-runtime-ktx:2.7.1'
	implementation 'com.google.android.material:material:1.5.0'
	//noinspection LifecycleAnnotationProcessorWithJava8
	kapt 'androidx.lifecycle:lifecycle-compiler:2.4.0'

	implementation 'androidx.room:room-runtime:2.4.1'
	implementation 'androidx.room:room-ktx:2.4.1'
	kapt 'androidx.room:room-compiler:2.4.1'

	implementation 'com.squareup.okhttp3:okhttp:4.9.1'
	implementation 'com.squareup.okio:okio:2.10.0'
	implementation 'org.jsoup:jsoup:1.14.3'

	implementation 'com.hannesdorfmann:adapterdelegates4-kotlin-dsl:4.3.1'
	implementation 'com.hannesdorfmann:adapterdelegates4-kotlin-dsl-viewbinding:4.3.1'

	implementation 'io.insert-koin:koin-android:3.1.5'
	implementation 'io.coil-kt:coil-base:1.4.0'
	implementation 'com.davemorrissey.labs:subsampling-scale-image-view-androidx:3.10.0'
	implementation 'com.github.solkin:disk-lru-cache:1.4'

	debugImplementation 'com.squareup.leakcanary:leakcanary-android:2.8.1'

	testImplementation 'junit:junit:4.13.2'
	testImplementation 'com.google.truth:truth:1.1.3'
	testImplementation 'org.json:json:20211205'
	testImplementation 'org.jetbrains.kotlinx:kotlinx-coroutines-test:1.6.0'
	testImplementation 'io.insert-koin:koin-test-junit4:3.1.5'

	androidTestImplementation 'androidx.test:runner:1.4.0'
	androidTestImplementation 'androidx.test:rules:1.4.0'
	androidTestImplementation 'androidx.test:core-ktx:1.4.0'
	androidTestImplementation 'androidx.test.ext:junit-ktx:1.1.3'
	androidTestImplementation 'androidx.room:room-testing:2.4.1'
	androidTestImplementation 'com.google.truth:truth:1.1.3'
}